*ASM XOPTS(NOEPILOG,EDF,SP) 
         TITLE 'DCNEPLTS:  NERDC CICS PLT SHUTDOWN PROGRAM' 
*********************************************************************** 
* 
* COPYRIGHT (C) 2002 by Steve Ware.  All rights reserved. 
* 
* This program is provided on an "as is" basis.  It may be 
* freely copied and distributed as long as it is not offered 
* for commercial sale, and as long as this copyright notice 
* is included.  No warranties are expressed or implied. 
* Use this program at your own risk. 
* 
*********************************************************************** 
* THIS PROGRAM EXECUTES AT SHUTDOWN TIME FOR ALL NERDC 
* CICS REGIONS.  IT IS INVOKED VIA THE PLT. 
*********************************************************************** 
* MAINTENANCE LOG: 
* ================ 
* 03/26/02  SFW001 
* CREATTION DATE.  PRIMARY IMPLEMENTATION IS TO PERFORM A SET 
* JOURNAL FLUSH COMMAND FOR EACH MVS LOGGER USER JOURNAL. 
* NOTE:  CURRENTLY, ERROR HANDLING IN MINIMAL OR NON-EXISTENT. 
*********************************************************************** 
         SPACE 
DFHEISTG DSECT                         DYNAMIC STORAGE 
JOURNAL  DS    CL8                     JOURNAL NAME 
RESP     DS    F                       RESPSONSE CODE 
         EJECT 
DCNEPLTS DFHEIENT                      CSECT BEGIN 
DCNEPLTS AMODE 31 , 
DCNEPLTS RMODE ANY , 
         SPACE , 
         EXEC CICS INQUIRE ,                                           +
               JOURNALNAME ,                                           +
               START ,                                                 +
               RESP(RESP) , 
         SPACE , 
         CLC   RESP,DFHRESP(NORMAL)    NORMAL RESPONSE? 
         BNE   RETURN                  ..NO, RETURN TO CICS 
         SPACE , 
INQJNEXT DS    0H                      INQUIRE UPON NEXT JOURNAL NAME 
         EXEC CICS INQUIRE ,                                           +
               JOURNALNAME(JOURNAL) ,                                  +
               NEXT ,                                                  +
               RESP(RESP) , 
         SPACE , 
         CLC   RESP,DFHRESP(NORMAL)    NORMAL RESPONSE? 
         BNE   RETURN                  ..NO, RETURN TO CICS 
         SPACE , 
         EXEC CICS SET ,                                               + 
               JOURNALNAME(JOURNAL) ,                                  + 
               FLUSH ,                                                 + 
               RESP(RESP) , 
         SPACE , 
         B     INQJNEXT                ..YES, INQUIRE UPON NEXT ONE 
         SPACE , 
RETURN   DS    0H                      CLEANUP AND RETURN 
         SPACE , 
         EXEC CICS INQUIRE ,                                           + 
               JOURNALNAME ,                                           + 
               END ,                                                   + 
               RESP(RESP) , 
         SPACE , 
         EXEC CICS RETURN ,            RETURN CONTROL TO CICS 
         EJECT 
PGMID    DC    CL8'DCNEPLTS'           CICS PPT ENTRY NAME 
         LTORG 
         END   DCNEPLTS